1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
{ stdenv, fetchurl, libidn, openssl, makeWrapper, fetchhg
, lua5, luasocket, luasec, luaexpat, luafilesystem, luabitop, luaevent ? null, luadbi ? null
, withLibevent ? true, withDBI ? true
, withCommunityModules ? [], extraLibs ? [], extraModules ? []
}:
assert withLibevent -> luaevent != null;
assert withDBI -> luadbi != null;
with stdenv.lib;
let
libs = [ luasocket luasec luaexpat luafilesystem luabitop ]
++ optional withLibevent luaevent
++ optional withDBI luadbi
++ extraLibs;
getPath = lib : type : "${lib}/lib/lua/${lua5.luaversion}/?.${type};${lib}/share/lua/${lua5.luaversion}/?.${type}";
getLuaPath = lib : getPath lib "lua";
getLuaCPath = lib : getPath lib "so";
copyModule = name : "cp -rv $communityModules/mod_${name} $out/lib/prosody/modules/";
copyExtraModule = path: "n=0; for i in ${path}/*; do n=1; done; if [[ $n -gt 0 ]]; then cp -rv ${path}/* $out/lib/prosody/modules/; fi";
luaPath = concatStringsSep ";" (map getLuaPath libs);
luaCPath = concatStringsSep ";" (map getLuaCPath libs);
copyModules = concatStringsSep ";" (map copyModule withCommunityModules);
copyExtraModules = concatStringsSep ";" (map copyExtraModule extraModules);
in
stdenv.mkDerivation rec {
version = "0.11.3";
pname = "prosody";
src = fetchurl {
url = "http://prosody.im/downloads/source/${pname}-${version}.tar.gz";
sha256 = "11xz4milv2962qf75vrdwsvd8sy2332nf69202rmvz5989pvvnng";
};
communityModules = fetchhg {
url = "https://hg.prosody.im/prosody-modules/";
rev = "b54e98d5c4a1";
sha256 = "0bzn92j48krb2zhp9gn5bbn5sg0qv15j5lpxfszwqdln3lpmrvzg";
};
buildInputs = [ lua5 luasocket luasec luaexpat luabitop libidn openssl makeWrapper ]
++ optional withLibevent luaevent
++ optional withDBI luadbi;
configureFlags = [
"--ostype=linux"
"--with-lua-include=${lua5}/include"
"--with-lua=${lua5}"
];
postInstall = ''
${copyModules}
${copyExtraModules}
wrapProgram $out/bin/prosody \
--set LUA_PATH '${luaPath};' \
--set LUA_CPATH '${luaCPath};'
wrapProgram $out/bin/prosodyctl \
--add-flags '--config "/etc/prosody/prosody.cfg.lua"' \
--set LUA_PATH '${luaPath};' \
--set LUA_CPATH '${luaCPath};'
'';
passthru.communityModules = withCommunityModules;
meta = {
description = "Open-source XMPP application server written in Lua";
license = licenses.mit;
homepage = http://www.prosody.im;
platforms = platforms.linux;
maintainers = [];
};
}
|
