...

15 files changed, 652 insertions, 6 deletions

diff --git a/accounts/gkleen@sif/shell/default.nix b/accounts/gkleen@sif/shell/default.nix
index 85e034d6..5025dd90 100644
--- a/accounts/gkleen@sif/shell/default.nix
+++ b/accounts/gkleen@sif/shell/default.nix
@@ -96,6 +96,12 @@
             # "${config.programs.niri.package}/share/wayland-sessions/niri.desktop"
           ];
           username = builtins.toJSON config.home.username;
+          mdi = builtins.toJSON (pkgs.fetchFromGitHub {
+            owner = "Templarian";
+            repo = "MaterialDesign";
+            rev = "2424e748e0cc63ab7b9c095a099b9fe239b737c0";
+            hash = "sha256-QMGl7soAhErrrnY3aKOZpt49yebkSNzy10p/v5OaqQ0=";
+          });
         };
       };
     };
diff --git a/accounts/gkleen@sif/shell/quickshell-plugins/CMakeLists.txt b/accounts/gkleen@sif/shell/quickshell-plugins/CMakeLists.txt
index 2123ed35..a7e88fa7 100644
--- a/accounts/gkleen@sif/shell/quickshell-plugins/CMakeLists.txt
+++ b/accounts/gkleen@sif/shell/quickshell-plugins/CMakeLists.txt
@@ -92,7 +92,7 @@ endfunction()
 cmake_minimum_required(VERSION 3.20)
 project(custom LANGUAGES CXX)
 
-find_package(Qt6 REQUIRED COMPONENTS Core Qml)
+find_package(Qt6 REQUIRED COMPONENTS Core Qml DBus)
 
 qt_standard_project_setup(REQUIRES 6.6)
 
@@ -102,16 +102,32 @@ qt6_add_qml_module(customplugin
     PLUGIN_TARGET customplugin
 )
 
-target_sources(customplugin PRIVATE
-    Chrono.cpp Chrono.hpp
-    FileSelector.cpp FileSelector.hpp
+set_source_files_properties(org.keepassxc.KeePassXC.MainWindow.xml PROPERTIES
+        CLASSNAME DBusKeePassXC
+        NO_NAMESPACE TRUE
 )
 
+qt_add_dbus_interface(DBUS_INTERFACES
+        org.keepassxc.KeePassXC.MainWindow.xml
+        dbus_keepassxc
+)
+
+include_directories(${CMAKE_SOURCE_DIR}/build)
+
 target_compile_features(customplugin PUBLIC cxx_std_26)
 
 target_link_libraries(customplugin PRIVATE
     Qt6::Core
     Qt6::Qml
+    Qt6::DBus
+)
+
+target_sources(customplugin PRIVATE
+    Chrono.cpp Chrono.hpp
+    FileSelector.cpp FileSelector.hpp
+    KeePassXC.cpp KeePassXC.hpp
+    Systemd.cpp Systemd.hpp
+    ${DBUS_INTERFACES}
 )
 
 install_qml_module(customplugin)
diff --git a/accounts/gkleen@sif/shell/quickshell-plugins/KeePassXC.cpp b/accounts/gkleen@sif/shell/quickshell-plugins/KeePassXC.cpp
new file mode 100644
index 00000000..f6e4dd6e
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell-plugins/KeePassXC.cpp
@@ -0,0 +1,18 @@
+#include "KeePassXC.hpp"
+
+#include <QDBusConnection>
+
+KeePassXC::KeePassXC() {
+  this->service = new DBusKeePassXC(DBusKeePassXC::staticInterfaceName(), "/keepassxc", QDBusConnection::sessionBus(), this);
+}
+KeePassXC::~KeePassXC() {
+  if (this->service)
+    delete this->service;
+}
+
+void KeePassXC::lockAllDatabases() {
+  if (!this->service)
+    return;
+
+  this->service->lockAllDatabases();
+}
diff --git a/accounts/gkleen@sif/shell/quickshell-plugins/KeePassXC.hpp b/accounts/gkleen@sif/shell/quickshell-plugins/KeePassXC.hpp
new file mode 100644
index 00000000..c4cd71e0
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell-plugins/KeePassXC.hpp
@@ -0,0 +1,21 @@
+#pragma once
+
+#include "dbus_keepassxc.h"
+
+#include <QObject>
+#include <QtQmlIntegration/qqmlintegration.h>
+
+class KeePassXC : public QObject {
+  Q_OBJECT;
+  QML_SINGLETON;
+  QML_ELEMENT;
+
+public:
+  explicit KeePassXC();
+  ~KeePassXC();
+
+  Q_INVOKABLE void lockAllDatabases();
+
+private:
+  DBusKeePassXC* service = nullptr;
+};
diff --git a/accounts/gkleen@sif/shell/quickshell-plugins/Systemd.cpp b/accounts/gkleen@sif/shell/quickshell-plugins/Systemd.cpp
new file mode 100644
index 00000000..9ccd8ba0
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell-plugins/Systemd.cpp
@@ -0,0 +1,16 @@
+#include "Systemd.hpp"
+
+#include <QDBusConnection>
+#include <QDBusMessage>
+
+void Systemd::stopUserUnit(const QString& unit, const QString& mode) {
+  QDBusMessage m = QDBusMessage::createMethodCall(
+    "org.freedesktop.systemd1",
+    "/org/freedesktop/systemd1",
+    "org.freedesktop.systemd1.Manager",
+    "StopUnit"
+  );
+  m << unit;
+  m << mode;
+  QDBusConnection::sessionBus().send(m);
+}
diff --git a/accounts/gkleen@sif/shell/quickshell-plugins/Systemd.hpp b/accounts/gkleen@sif/shell/quickshell-plugins/Systemd.hpp
new file mode 100644
index 00000000..883a96f3
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell-plugins/Systemd.hpp
@@ -0,0 +1,13 @@
+#pragma once
+
+#include <QObject>
+#include <QtQmlIntegration/qqmlintegration.h>
+
+class Systemd : public QObject {
+  Q_OBJECT;
+  QML_SINGLETON;
+  QML_ELEMENT;
+
+public:
+  Q_INVOKABLE void stopUserUnit(const QString& unit, const QString& mode);
+};
diff --git a/accounts/gkleen@sif/shell/quickshell-plugins/default.nix b/accounts/gkleen@sif/shell/quickshell-plugins/default.nix
index fafea90e..33b76f61 100644
--- a/accounts/gkleen@sif/shell/quickshell-plugins/default.nix
+++ b/accounts/gkleen@sif/shell/quickshell-plugins/default.nix
@@ -3,11 +3,19 @@
 , cmake
 , qt6
 , fmt
+, keepassxc
+, systemd
 }:
+
 stdenv.mkDerivation rec {
   name = "quickshell-custom";
 
   src = ./.;
+
+  prePatch = ''
+    cp ${keepassxc.src}/src/gui/org.keepassxc.KeePassXC.MainWindow.xml .
+  '';
+
   nativeBuildInputs = [ cmake qt6.wrapQtAppsHook ];
   buildInputs = [
     qt6.qtbase
diff --git a/accounts/gkleen@sif/shell/quickshell/Bar.qml b/accounts/gkleen@sif/shell/quickshell/Bar.qml
index 38225d74..3652af54 100644
--- a/accounts/gkleen@sif/shell/quickshell/Bar.qml
+++ b/accounts/gkleen@sif/shell/quickshell/Bar.qml
@@ -64,6 +64,13 @@ PanelWindow {
     anchors.verticalCenter: parent.verticalCenter
     spacing: 0
 
+    PipewireWidget {}
+
+    Item {
+      height: parent.height
+      width: 4
+    }
+
     SystemTray {}
 
     Item {
diff --git a/accounts/gkleen@sif/shell/quickshell/Clock.qml b/accounts/gkleen@sif/shell/quickshell/Clock.qml
index 382af168..4644d5e7 100644
--- a/accounts/gkleen@sif/shell/quickshell/Clock.qml
+++ b/accounts/gkleen@sif/shell/quickshell/Clock.qml
@@ -99,9 +99,10 @@ Item {
           id: clockTooltipContent
 
           margin: 8
-          leftMargin: 0
 
           ColumnLayout {
+            anchors.centerIn: parent
+
             Text {
               id: yearLabel
 
diff --git a/accounts/gkleen@sif/shell/quickshell/Lockscreen.qml b/accounts/gkleen@sif/shell/quickshell/Lockscreen.qml
index cc82a275..8e739359 100644
--- a/accounts/gkleen@sif/shell/quickshell/Lockscreen.qml
+++ b/accounts/gkleen@sif/shell/quickshell/Lockscreen.qml
@@ -2,6 +2,9 @@ import Quickshell
 import Quickshell.Wayland
 import Quickshell.Io
 import Quickshell.Services.Pam
+import Quickshell.Services.Mpris
+import Custom as Custom
+import qs.Services
 import QtQml
 
 Scope {
@@ -38,9 +41,19 @@ Scope {
   WlSessionLock {
     id: lock
 
-    onLockedChanged: {
+    onLockStateChanged: {
       if (!locked && pam.active)
         pam.abort();
+
+      if (locked) {
+        Custom.KeePassXC.lockAllDatabases();
+        Array.from(Mpris.players.values).forEach(player => {
+          if (player.canPause && player.isPlaying)
+            player.pause();
+        });
+        // Custom.Systemd.stopUserUnit("gpg-agent.service", "replace");
+        GpgAgent.reloadAgent();
+      }
     }
 
     WlSessionLockSurface {
diff --git a/accounts/gkleen@sif/shell/quickshell/MaterialDesignIcon.qml b/accounts/gkleen@sif/shell/quickshell/MaterialDesignIcon.qml
new file mode 100644
index 00000000..387dcc8b
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell/MaterialDesignIcon.qml
@@ -0,0 +1,24 @@
+import QtQuick
+import QtQuick.Effects
+
+Item {
+  id: icon
+
+  required property string icon
+  property color color: "white"
+
+  Image {
+    id: sourceImage
+    source: "file://" + @mdi@ + "/svg/" + icon.icon + ".svg"
+    anchors.fill: parent
+
+    layer.enabled: true
+    layer.effect: MultiEffect {
+      id: effect
+
+      brightness: 1
+      colorization: 1
+      colorizationColor: icon.color
+    }
+  }
+}
diff --git a/accounts/gkleen@sif/shell/quickshell/PipewireWidget.qml b/accounts/gkleen@sif/shell/quickshell/PipewireWidget.qml
new file mode 100644
index 00000000..5bf0ac3a
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell/PipewireWidget.qml
@@ -0,0 +1,354 @@
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Controls.Fusion
+import Quickshell
+import Quickshell.Services.Pipewire
+import Quickshell.Widgets
+
+Item {
+  height: parent.height
+  width: volumeIcon.width + 8
+  anchors.verticalCenter: parent.verticalCenter
+
+  PwObjectTracker {
+    objects: [Pipewire.defaultAudioSink]
+  }
+
+  WrapperMouseArea {
+    id: widgetMouseArea
+
+    anchors.fill: parent
+    hoverEnabled: true
+    cursorShape: Qt.PointingHandCursor
+
+    onClicked: {
+      if (!Pipewire.defaultAudioSink)
+        return;
+      Pipewire.defaultAudioSink.audio.muted = !Pipewire.defaultAudioSink.audio.muted;
+    }
+
+    property real sensitivity: (1 / 20) / 120
+    onWheel: event => {
+      if (!Pipewire.defaultAudioSink)
+        return;
+      Pipewire.defaultAudioSink.audio.volume += event.angleDelta.y * sensitivity;
+    }
+
+    Rectangle {
+      id: volumeWidget
+
+      anchors.fill: parent
+      color: {
+        if (widgetMouseArea.containsMouse)
+          return "#33808080";
+        return "transparent";
+      }
+
+      Item {
+        anchors.fill: parent
+
+        MaterialDesignIcon {
+          id: volumeIcon
+
+          width: 16
+          height: 16
+          anchors.centerIn: parent
+
+          icon: {
+            if (!Pipewire.defaultAudioSink || Pipewire.defaultAudioSink.audio.muted)
+              return "volume-off";
+            if (Pipewire.defaultAudioSink.audio.volume <= 0.33)
+              return "volume-low";
+            if (Pipewire.defaultAudioSink.audio.volume <= 0.67)
+              return "volume-medium";
+            return "volume-high";
+          }
+          color: "#555"
+        }
+      }
+    }
+  }
+
+  Loader {
+    id: tooltipLoader
+
+    active: false
+
+    Connections {
+      target: widgetMouseArea
+      function onContainsMouseChanged() {
+        if (widgetMouseArea.containsMouse)
+          tooltipLoader.active = true;
+      }
+    }
+
+    PwObjectTracker {
+      objects: Pipewire.devices
+    }
+    PwObjectTracker {
+      objects: Pipewire.nodes
+    }
+
+    sourceComponent: PopupWindow {
+      id: tooltip
+
+      property bool openPopup: false
+      property bool nextVisible: widgetMouseArea.containsMouse || tooltipMouseArea.containsMouse || openPopup
+
+      anchor {
+        item: widgetMouseArea
+        edges: Edges.Bottom | Edges.Left
+      }
+      visible: false
+
+      onNextVisibleChanged: hangTimer.restart()
+
+      Timer {
+        id: hangTimer
+        interval: 100
+        onTriggered: {
+          tooltip.visible = tooltip.nextVisible;
+          if (!tooltip.visible)
+            tooltipLoader.active = false;
+        }
+      }
+
+      implicitWidth: tooltipContent.width
+      implicitHeight: tooltipContent.height
+      color: "black"
+
+      WrapperMouseArea {
+        id: tooltipMouseArea
+
+        hoverEnabled: true
+        enabled: true
+
+        anchors.fill: parent
+
+        WrapperItem {
+          id: tooltipContent
+
+          margin: 8
+          bottomMargin: 8 + Math.max(0, 200 - tooltipLayout.implicitHeight)
+
+          GridLayout {
+            id: tooltipLayout
+
+            columns: 4
+
+            Repeater {
+              model: Array.from(Pipewire.devices.values).filter(dev => dev.type == "Audio/Device")
+
+              Item {
+                id: descItem
+
+                required property var modelData
+                required property int index
+
+                Layout.column: 0
+                Layout.row: index
+
+                implicitWidth: descText.contentWidth
+                implicitHeight: descText.contentHeight
+
+                Text {
+                  id: descText
+
+                  color: "white"
+                  font.pointSize: 10
+                  font.family: "Fira Sans"
+
+                  text: descItem.modelData.description
+                }
+              }
+            }
+
+            Repeater {
+              id: defaultSinkRepeater
+
+              model: {
+                Array.from(Pipewire.devices.values)
+                  .filter(dev => dev.type == "Audio/Device")
+                  .map(device => Array.from(Pipewire.nodes.values).find(node => node.type == PwNodeType.AudioSink && node.device?.id == device.id ));
+              }
+
+              Item {
+                id: defaultSinkItem
+
+                required property var modelData
+                required property int index
+
+                PwObjectTracker {
+                  objects: [defaultSinkItem.modelData]
+                }
+
+                Layout.column: 1
+                Layout.row: index
+
+                Layout.fillHeight: true
+
+                implicitWidth: 16 + 8
+
+                WrapperMouseArea {
+                  id: defaultSinkMouseArea
+
+                  anchors.fill: parent
+                  hoverEnabled: true
+                  cursorShape: Qt.PointingHandCursor
+
+                  onClicked: {
+                    Pipewire.preferredDefaultAudioSink = defaultSinkItem.modelData
+                  }
+
+                  Rectangle {
+                    id: defaultSinkWidget
+
+                    anchors.fill: parent
+                    color: {
+                      if (defaultSinkMouseArea.containsMouse)
+                        return "#33808080";
+                      return "transparent";
+                    }
+
+                    MaterialDesignIcon {
+                      width: 16
+                      height: 16
+                      anchors.centerIn: parent
+
+                      icon: {
+                        if (defaultSinkItem.modelData?.id == Pipewire.defaultAudioSink?.id)
+                          return "speaker";
+                        return "speaker-off";
+                      }
+                      color: icon == "speaker" ? "white" : "#555"
+                    }
+                  }
+                }
+              }
+            }
+
+            Repeater {
+              id: defaultSourceRepeater
+
+              model: {
+                Array.from(Pipewire.devices.values)
+                  .filter(dev => dev.type == "Audio/Device")
+                  .map(device => Array.from(Pipewire.nodes.values).find(node => node.type == PwNodeType.AudioSource && node.device?.id == device.id ));
+              }
+
+              Item {
+                id: defaultSourceItem
+
+                required property var modelData
+                required property int index
+
+                PwObjectTracker {
+                  objects: [defaultSourceItem.modelData]
+                }
+
+                Layout.column: 2
+                Layout.row: index
+
+                Layout.fillHeight: true
+
+                implicitWidth: 16 + 8
+
+                WrapperMouseArea {
+                  id: defaultSourceMouseArea
+
+                  anchors.fill: parent
+                  hoverEnabled: true
+                  cursorShape: Qt.PointingHandCursor
+
+                  onClicked: {
+                    Pipewire.preferredDefaultAudioSource = defaultSourceItem.modelData
+                  }
+
+                  Rectangle {
+                    id: defaultSourceWidget
+
+                    anchors.fill: parent
+                    color: {
+                      if (defaultSourceMouseArea.containsMouse)
+                        return "#33808080";
+                      return "transparent";
+                    }
+
+                    MaterialDesignIcon {
+                      width: 16
+                      height: 16
+                      anchors.centerIn: parent
+
+                      icon: {
+                        if (defaultSourceItem.modelData?.id == Pipewire.defaultAudioSource?.id)
+                          return "microphone";
+                        return "microphone-off";
+                      }
+                      color: icon == "microphone" ? "white" : "#555"
+                    }
+                  }
+                }
+              }
+            }
+
+            Repeater {
+              id: profileRepeater
+
+              model: Array.from(Pipewire.devices.values).filter(dev => dev.type == "Audio/Device")
+
+              Item {
+                id: profileItem
+
+                required property var modelData
+                required property int index
+
+                PwObjectTracker {
+                  objects: [profileItem.modelData]
+                }
+
+                Layout.column: 3
+                Layout.row: index
+
+                Layout.fillWidth: true
+
+                implicitWidth: Math.max(profileBox.implicitWidth, 300)
+                implicitHeight: profileBox.height
+
+                ComboBox {
+                  id: profileBox
+
+                  model: profileItem.modelData.profiles
+
+                  textRole: "description"
+                  valueRole: "index"
+                  onActivated: profileItem.modelData.setProfile(currentValue)
+
+                  anchors.fill: parent
+
+                  implicitContentWidthPolicy: ComboBox.WidestText
+
+                  Connections {
+                    target: profileItem.modelData
+                    function onCurrentProfileChanged() {
+                      profileBox.currentIndex = Array.from(profileItem.modelData.profiles).findIndex(profile => profile.index == profileItem.modelData.currentProfile);
+                    }
+                  }
+                  Component.onCompleted: {
+                    profileBox.currentIndex = Array.from(profileItem.modelData.profiles).findIndex(profile => profile.index == profileItem.modelData.currentProfile);
+                  }
+
+                  Connections {
+                    target: profileBox.popup
+                    function onVisibleChanged() {
+                      tooltip.openPopup = profileBox.popup.visible
+                    }
+                  }
+                }
+              }
+            }
+          }
+        }
+      }
+    }
+  }
+}
diff --git a/accounts/gkleen@sif/shell/quickshell/Services/GpgAgent.qml b/accounts/gkleen@sif/shell/quickshell/Services/GpgAgent.qml
new file mode 100644
index 00000000..3de69535
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell/Services/GpgAgent.qml
@@ -0,0 +1,18 @@
+pragma Singleton
+
+import Quickshell
+import Quickshell.Io
+
+Singleton {
+  id: root
+
+  Socket {
+    id: agentSocket
+    connected: true
+    path: `${Quickshell.env("XDG_RUNTIME_DIR")}/gnupg/S.gpg-agent`
+  }
+
+  function reloadAgent() {
+    agentSocket.write("RELOADAGENT\n")
+  }
+}
diff --git a/accounts/gkleen@sif/shell/quickshell/VolumeOSD.qml b/accounts/gkleen@sif/shell/quickshell/VolumeOSD.qml
new file mode 100644
index 00000000..3a78d91b
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell/VolumeOSD.qml
@@ -0,0 +1,129 @@
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import Quickshell.Services.Pipewire
+import Quickshell.Widgets
+
+Scope {
+  id: root
+
+  property bool show: false
+  property bool inhibited: true
+
+  PwObjectTracker {
+    objects: [ Pipewire.defaultAudioSink ]
+  }
+
+  Connections {
+    target: Pipewire.defaultAudioSink?.audio
+
+    function onVolumeChanged() {
+      root.show = true;
+      hideTimer.reset();
+    }
+    function onMutedChanged() {
+      root.show = true;
+      hideTimer.reset();
+    }
+  }
+
+  onShowChanged: {
+    if (show)
+      hideTimer.restart();
+  }
+
+  Timer {
+    id: hideTimer
+    interval: 2000
+    onTriggered: root.show = false
+  }
+
+  Timer {
+    id: startInhibit
+    interval: 100
+    running: true
+    onTriggered: root.inhibited = false;
+  }
+
+  LazyLoader {
+    active: root.show && !root.inhibited
+
+    Variants {
+      model: Quickshell.screens
+
+      delegate: Scope {
+        id: screenScope
+
+        required property var modelData
+
+        PanelWindow {
+          id: window
+
+          screen: screenScope.modelData
+
+          anchors.top: true
+          margins.top: (screen.height - window.height) / 2
+          exclusiveZone: 0
+
+          implicitWidth: 400
+          implicitHeight: 50
+
+          mask: Region {}
+
+          color: "transparent"
+
+          Rectangle {
+            anchors.fill: parent
+            color: Qt.rgba(0, 0, 0, 0.75)
+          }
+
+          RowLayout {
+            id: layout
+
+            anchors.centerIn: parent
+
+            height: 50 - 8*2
+            width: 400 - 8*2
+
+            MaterialDesignIcon {
+              id: volumeIcon
+
+              implicitWidth: parent.height
+              implicitHeight: parent.height
+
+              icon: {
+                if (!Pipewire.defaultAudioSink || Pipewire.defaultAudioSink.audio.muted)
+                  return "volume-off";
+                if (Pipewire.defaultAudioSink.audio.volume <= 0.33)
+                  return "volume-low";
+                if (Pipewire.defaultAudioSink.audio.volume <= 0.67)
+                  return "volume-medium";
+                return "volume-high";
+              }
+            }
+
+            Rectangle {
+              Layout.fillWidth: true
+
+              implicitHeight: 10
+
+              color: "#50ffffff"
+
+              Rectangle {
+                anchors {
+                  left: parent.left
+                  top: parent.top
+                  bottom: parent.bottom
+                }
+
+                color: Pipewire.defaultAudioSink?.audio.muted ? "#70ffffff" : "white"
+
+                implicitWidth: parent.width * (Pipewire.defaultAudioSink?.audio.volume ?? 0)
+              }
+            }
+          }
+        }
+      }
+    }
+  }
+}
diff --git a/accounts/gkleen@sif/shell/quickshell/shell.qml b/accounts/gkleen@sif/shell/quickshell/shell.qml
index 1da9457d..3657f77f 100644
--- a/accounts/gkleen@sif/shell/quickshell/shell.qml
+++ b/accounts/gkleen@sif/shell/quickshell/shell.qml
@@ -41,4 +41,6 @@ ShellRoot {
   }
 
   Lockscreen {}
+
+  VolumeOSD {}
 }