1 files changed, 49 insertions, 0 deletions

diff --git a/home-modules/lmu-hausschrift/default.nix b/home-modules/lmu-hausschrift/default.nix
new file mode 100644
index 00000000..c3344947
--- /dev/null
+++ b/home-modules/lmu-hausschrift/default.nix
@@ -0,0 +1,49 @@
+{ config, pkgs, lib, ... }:
+
+with lib;
+
+{
+  options = {
+    fonts.lmu-hausschrift.enable = mkEnableOption "LMU Hausschrift";
+  };
+
+  config = mkIf config.fonts.lmu-hausschrift.enable {
+    sops.secrets."lmu-hausschrift.tar.zstd" = {
+      format = "binary";
+      sopsFile = ./lmu-hausschrift.tar.zstd;
+    };
+
+    xdg.configFile = {
+      "fontconfig/conf.d/20-lmu-hausschrift.conf".text = ''
+        <?xml version='1.0'?>
+
+        <!DOCTYPE fontconfig SYSTEM 'urn:fontconfig:fonts.dtd'>
+        <fontconfig>
+          <dir>${config.home.homeDirectory}/.local/share/lmu-hausschrift</dir>
+        </fontconfig>
+      '';
+    };
+
+    systemd.user.services.sops-nix = {
+      Service = {
+        ExecStartPost = pkgs.writeShellScript "unpack-lmu-hausschrift.sh" ''
+          set -xe
+
+          out=''${XDG_RUNTIME_DIR:-/tmp}/lmu-hausschrift
+          src="${config.sops.secrets."lmu-hausschrift.tar.zstd".path}"
+          src=''${src#"%r/"}
+          src=''${XDG_RUNTIME_DIR:-/tmp}/"''${src}"
+
+          umask 07077
+
+          if [[ ! -d "''${out}" ]]; then
+            ${pkgs.coreutils}/bin/mkdir -p "''${out}"
+            ${pkgs.gnutar}/bin/tar -xaf "''${src}" -C "''${out}"
+
+            ${pkgs.coreutils}/bin/ln -sfT "''${out}" "${config.home.homeDirectory}/.local/share/lmu-hausschrift"
+          fi
+        '';
+      };
+    };
+  };
+}