1 files changed, 159 insertions, 0 deletions

diff --git a/accounts/gkleen@sif/shell/quickshell/SystemTray.qml b/accounts/gkleen@sif/shell/quickshell/SystemTray.qml
new file mode 100644
index 00000000..55b1690e
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell/SystemTray.qml
@@ -0,0 +1,159 @@
+import QtQuick
+import Quickshell
+import Quickshell.Widgets
+import Quickshell.Services.SystemTray
+
+Item {
+  anchors.verticalCenter: parent.verticalCenter
+  width: systemTrayRow.childrenRect.width
+  height: parent.height
+  clip: true
+
+  Row {
+    id: systemTrayRow
+    anchors.centerIn: parent
+    width: childrenRect.width
+    height: parent.height
+    spacing: 0
+
+    Repeater {
+      model: ScriptModel {
+        values: {
+          var trayItems = Array.from(SystemTray.items.values).filter(item => item.status !== Status.Passive);
+          trayItems.sort((a, b) => a.category !== b.category ? b.category - a.category : a.id.localeCompare(b.id))
+          return trayItems;
+        }
+      }
+
+      delegate: Item {
+        id: trayItemWrapper
+
+        property var trayItem: modelData
+        property string iconSource: {
+          let icon = trayItem && trayItem.icon
+          if (typeof icon === 'string' || icon instanceof String) {
+            if (icon.includes("?path=")) {
+              const split = icon.split("?path=")
+              if (split.length !== 2)
+                return icon
+              const name = split[0]
+              const path = split[1]
+              const fileName = name.substring(
+                               name.lastIndexOf("/") + 1)
+              return `file://${path}/${fileName}`
+            }
+            return icon
+          }
+          return ""
+        }
+
+        width: 16
+        height: parent.height
+        anchors.verticalCenter: parent.verticalCenter
+
+        WrapperMouseArea {
+          id: trayItemArea
+
+          anchors.fill: parent
+          acceptedButtons: Qt.LeftButton | Qt.RightButton
+          hoverEnabled: true
+          cursorShape: trayItem.onlyMenu ? Qt.ArrowCursor : Qt.PointingHandCursor
+          onClicked: mouse => {
+            if (!trayItem)
+              return
+
+            if (mouse.button === Qt.LeftButton
+              && !trayItem.onlyMenu) {
+              trayItem.activate()
+              return
+            }
+
+            if (trayItem.hasMenu) {
+              var globalPos = mapToGlobal(0, 0)
+              var currentScreen = screen || Screen
+              var screenX = currentScreen.x || 0
+              var relativeX = globalPos.x - screenX
+              menuAnchor.menu = trayItem.menu
+              menuAnchor.anchor.window = bar
+              menuAnchor.anchor.rect = Qt.rect(
+                  relativeX,
+                  21,
+                  parent.width, 1)
+              menuAnchor.open()
+            }
+          }
+
+          IconImage {
+            anchors.centerIn: parent
+            width: parent.width
+            height: parent.width
+            source: trayItemWrapper.iconSource
+            asynchronous: true
+            smooth: true
+            mipmap: true
+          }
+        }
+
+        PopupWindow {
+          id: tooltip
+
+          property bool nextVisible: (trayItem.tooltipTitle || trayItem.tooltipDescription) && (trayItemArea.containsMouse || tooltipMouseArea.containsMouse) && !menuAnchor.visible
+
+          anchor {
+            item: trayItemArea
+            edges: Edges.Bottom
+          }
+
+          visible: false
+          onNextVisibleChanged: hangTimer.restart()
+
+          Timer {
+            id: hangTimer
+            interval: 100
+            onTriggered: tooltip.visible = tooltip.nextVisible
+          }
+
+          color: "black"
+
+          implicitWidth: Math.max(tooltipTitle.contentWidth, tooltipDescription.contentWidth) + 16
+          implicitHeight: tooltipTitle.contentHeight + tooltipDescription.contentHeight + 16
+
+          WrapperMouseArea {
+            id: tooltipMouseArea
+
+            hoverEnabled: true
+            enabled: true
+
+            margin: 8
+
+            Column {
+              Text {
+                id: tooltipTitle
+
+                font.pointSize: 10
+                font.family: "Fira Sans"
+                font.bold: true
+                color: "white"
+
+                text: trayItem.tooltipTitle
+              }
+
+              Text {
+                id: tooltipDescription
+
+                font.pointSize: 10
+                font.family: "Fira Sans"
+                color: "white"
+
+                text: trayItem.tooltipDescription
+              }
+            }
+          }
+        }
+      }
+    }
+  }
+  QsMenuAnchor {
+    id: menuAnchor
+  }
+}