...

1 files changed, 53 insertions, 0 deletions

diff --git a/overlays/nix-direnv/default.nix b/overlays/nix-direnv/default.nix
new file mode 100644
index 00000000..7c488e4e
--- /dev/null
+++ b/overlays/nix-direnv/default.nix
@@ -0,0 +1,53 @@
+{ final, prev, ... }: {
+  nix-direnv = prev.resholve.mkDerivation rec {
+    pname = "nix-direnv";
+    version = "3.0.6";
+
+    patches = [
+      ./static-nix.patch
+    ];
+
+    src = prev.fetchFromGitHub {
+      owner = "nix-community";
+      repo = "nix-direnv";
+      rev = version;
+      hash = "sha256-oNqhPqgQT92yxbKmcgX4F3e2yTUPyXYG7b2xQm3TvQw=";
+    };
+
+    installPhase = ''
+      runHook preInstall
+      install -m400 -D direnvrc $out/share/nix-direnv/direnvrc
+      runHook postInstall
+    '';
+
+    solutions = {
+      default = {
+        scripts = [ "share/nix-direnv/direnvrc" ];
+        interpreter = "none";
+        inputs = with final; [ coreutils nix-monitored ];
+        fake = {
+          builtin = [
+            "PATH_add"
+            "direnv_layout_dir"
+            "has"
+            "log_error"
+            "log_status"
+            "watch_file"
+          ];
+          function = [
+            # not really a function - this is in an else branch for macOS/homebrew that
+            # cannot be reached when built with nix
+            "shasum"
+          ];
+        };
+        keep = {
+          "$cmd" = true;
+          "$direnv" = true;
+        };
+        execer = [
+          "cannot:${prev.lib.getExe' final.nix-monitored "nix"}"
+        ];
+      };
+    };
+  };
+}