{
  packageOverrides = pkgs: with pkgs; {
    chromium-wrapper = symlinkJoin {
      name = ''${chromium.name}-wrapped'';
      paths = [ chromium ];
      buildInputs = [ makeWrapper ];
      postBuild = ''
        wrapProgram $out/bin/chromium \
	  --add-flags --force-device-scale-factor=1.6
      '';
    };
    chrome-wrapper = symlinkJoin {
      name = ''${google-chrome-dev.name}-wrapped'';
      paths = [ google-chrome-dev ];
      buildInputs = [ makeWrapper ];
      postBuild = ''
        wrapProgram $out/bin/google-chrome-unstable \
	  --add-flags --force-device-scale-factor=1.6
        ln -s $out/bin/google-chrome-unstable $out/bin/chrome

        rm $out/share/applications/google-chrome-unstable.desktop
        substitute ${google-chrome-dev}/share/applications/google-chrome-unstable.desktop $out/share/applications/google-chrome-unstable.desktop --replace "${google-chrome-dev}" "$out"
      '';
    };
    gnupg = lib.overrideDerivation gnupg (oldAttrs: {
      postInstall = ''
        ln -s $out/bin/gpg2 $out/bin/gpg
      '';
    });
    dunst-suspend = writeScriptBin "dunst-suspend" ''
      #!${pkgs.stdenv.shell}

      export PATH=${psmisc}/bin:$PATH

      killall -s USR1 -u "$(whoami)" -- dunst
      $@
      killall -s USR2 -u "$(whoami)" -- dunst
    '';
    gajim = lib.overrideDerivation gajim (old: {
      enableNotifications = true;
    });
    haskellPackages = haskellPackages.override {
      overrides = self: super: with super; {
        extended-reals = haskell.lib.doJailbreak extended-reals;
        pandoc-crossref = haskell.lib.dontTest pandoc-crossref;
      } // (import ../custom/thermoprint { inherit pkgs; });
    };
  } // (import ../utils/nix/default.nix) {};

  allowUnfree = true;

  chromium = {
    enableWideVine = true;
    hiDPI = true;
  };

  mpv = {
    vaapiSupport = true;
  };
}