{
  packageOverrides = pkgs: rec {
    chromium-wrapper = pkgs.symlinkJoin {
      name = ''${pkgs.chromium.name}-wrapped'';
      paths = [ pkgs.chromium ];
      buildInputs = [ pkgs.makeWrapper ];
      postBuild = ''
        wrapProgram $out/bin/chromium \
	  --add-flags --force-device-scale-factor=1.6
      '';
    };
    chrome-wrapper = pkgs.symlinkJoin {
      name = ''${pkgs.google-chrome.name}-wrapped'';
      paths = [ pkgs.google-chrome ];
      buildInputs = [ pkgs.makeWrapper ];
      postBuild = ''
        wrapProgram $out/bin/google-chrome-stable \
	  --add-flags --force-device-scale-factor=1.6
        ln -s $out/bin/google-chrome-stable $out/bin/chrome

        rm $out/share/applications/google-chrome.desktop
        substitute ${pkgs.google-chrome}/share/applications/google-chrome.desktop $out/share/applications/google-chrome.desktop --replace "${pkgs.google-chrome}" "$out"
      '';
    };
    gnupg = pkgs.lib.overrideDerivation pkgs.gnupg (oldAttrs: {
      postInstall = ''
        ln -s $out/bin/gpg2 $out/bin/gpg
      '';
    });
    dunst-suspend = pkgs.writeScriptBin "dunst-suspend" ''
      #!${pkgs.stdenv.shell}

      export PATH=${pkgs.psmisc}/bin:$PATH

      killall -s USR1 -u "$(whoami)" -- dunst
      $@
      killall -s USR2 -u "$(whoami)" -- dunst
    '';
  } // (import ../utils/nix/default.nix) {};

  allowUnfree = true;

  chromium = {
    enableWideVine = true;
    hiDPI = true;
  };

  mpv = {
    vaapiSupport = true;
  };
}