{ final, prev, ... }: {
  etesync-web = final.stdenv.mkDerivation (finalAttrs: {
    pname = "etesync-web";
    version = "0.6.1";

    patches = [
      (final.fetchpatch {
        name = "fix-server-url-usage.patch";
        url = "https://github.com/etesync/etesync-web/commit/7a03f8c69c12527d537ce9cb012a5e86a578aa9d.patch";
        hash = "sha256-qPwV+K3jiqAXZl2gYMzcNIcuG0raOyX/YjRWd7/5kU8=";
      })
    ];

    src = final.fetchFromGitHub {
      owner = "etesync";
      repo = "etesync-web";
      rev = "v${finalAttrs.version}";
      hash = "sha256-ZQpbeEIDj7cB0Y62uIw3qSClvwE4buVKh6ZPMfS53dY=";
    };

    yarnOfflineCache = final.fetchYarnDeps {
      yarnLock = finalAttrs.src + "/yarn.lock";
      hash = "sha256-YHZulUhgieDAV1jyweeoXwzoklTnf4ZvuVmgGmM2eBE=";
    };

    nativeBuildInputs = [
      final.nodejs final.yarnConfigHook final.yarnBuildHook
    ];

    REACT_APP_DEFAULT_API_PATH = "https://etesync.yggdrasil.li";
    NODE_OPTIONS = "--openssl-legacy-provider";

    installPhase = ''
      runHook preInstall

      cp -r build $out

      runHook postInstall
    '';
  });
}