{ final, prev, ... }: {
  etesync-dav =
    let
      inherit (final) lib stdenv python39 radicale3 callPackage;

      python = python39.override {
        packageOverrides = self: super: {
          flask-wtf = super.flask-wtf.overridePythonAttrs (old: rec {
            version = "0.15.1";
            src = old.src.override {
              inherit version;
              sha256 = "ff177185f891302dc253437fe63081e7a46a4e99aca61dfe086fb23e54fff2dc";
            };
            doCheck = false;
            disabledTests = [
              "test_outside_request"
            ];
            patches = [ ];
          });
          etebase = python.pkgs.callPackage ./etebase.nix { python39 = python; openssl = final.openssl_1_1; };
        };
      };
    in python.pkgs.buildPythonApplication rec {
      pname = "etesync-dav";
      version = "0.32.1";

      src = python.pkgs.fetchPypi {
        inherit pname version;
        sha256 = "a4e2ee83932755d29ac39c1e74005ec289880fd2d4d2164f09fe2464a294d720";
      };

      propagatedBuildInputs = with python.pkgs; [
        appdirs
        etebase
        etesync
        flask
        flask-wtf
        msgpack
        pysocks
        setuptools
        (python.pkgs.toPythonModule (radicale3.override { python3 = python; }))
        requests
      ] ++ requests.optional-dependencies.socks;

      doCheck = false;

      meta = with lib; {
        homepage = "https://www.etesync.com/";
        description = "Secure, end-to-end encrypted, and privacy respecting sync for contacts, calendars and tasks";
        license = licenses.gpl3;
        maintainers = with maintainers; [ thyol valodim ];
        broken = stdenv.isDarwin; # pyobjc-framework-Cocoa is missing
      };
    };
}