{ flakeInputs, final, prev, ... }: {
  etesync-dav = final.python312Packages.buildPythonApplication (finalAttrs:  rec {
    pname = "etesync-dav";
    version = "0.35.1";
    pyproject = true;

    src = prev.fetchFromGitHub {
      owner = "etesync";
      repo = "etesync-dav";
      tag = "v${finalAttrs.version}";
      hash = "sha256-y4BhU2kSn+RWqc5+pJQFhbwfat9cMWD0ED0EXJp25cY=";
    };

    patches = [
      (flakeInputs.nixpkgs + "/pkgs/by-name/et/etesync-dav/radicale-3-6-compat.patch")
      (prev.fetchpatch {
        url = "https://github.com/etesync/etesync-dav/pull/366.patch";
        hash = "sha256-WR+D6ZLMsvFzSFSGaensNxrs4VZAc9EoIwCfF6OPOSQ=";
      })
    ];
    pythonRelaxDeps = [ "radicale" ];

    build-system = with final.python312Packages; [ setuptools ];

    PYTHONPATH = final.python312Packages.makePythonPath dependencies;

    dependencies = with final.python312Packages; [
      appdirs
      etebase
      etesync
      flask
      flask-wtf
      msgpack
      requests
      (buildPythonApplication rec {
        pname = "radicale";
        version = "3.2.0";
        pyproject = true;

        src = prev.fetchFromGitHub {
          owner = "Kozea";
          repo = "Radicale";
          rev = "refs/tags/v${version}";
          hash = "sha256-RxC8VOfdTXJZiAroDHTKjJqGWu65Z5uyb4WK1LOqubQ=";
        };

        postPatch = ''
          sed -i '/addopts/d' setup.cfg
        '';

        build-system = [
          setuptools
        ];

        dependencies = [
          defusedxml
          passlib
          vobject
          pika
          python-dateutil
          pytz # https://github.com/Kozea/Radicale/issues/816
        ] ++ passlib.optional-dependencies.bcrypt;
      })
    ] ++ requests.optional-dependencies.socks;

    doCheck = false;
  });
}