{ final, prev, ... }: {
  etesync-dav = final.python3Packages.buildPythonApplication rec {
    pname = "etesync-dav";
    version = "0.35.1";
    pyproject = true;

    src = prev.fetchFromGitHub {
      owner = "etesync";
      repo = "etesync-dav";
      tag = "v${version}";
      hash = "sha256-y4BhU2kSn+RWqc5+pJQFhbwfat9cMWD0ED0EXJp25cY=";
    };

    build-system = with final.python3Packages; [ setuptools ];

    dependencies = with final.python3Packages; [
      appdirs
      etebase
      etesync
      flask
      flask-wtf
      msgpack
      requests
      requests.optional-dependencies.socks
      (buildPythonApplication rec {
        pname = "radicale";
        version = "3.2.0";
        pyproject = true;

        src = prev.fetchFromGitHub {
          owner = "Kozea";
          repo = "Radicale";
          rev = "refs/tags/v${version}";
          hash = "sha256-RxC8VOfdTXJZiAroDHTKjJqGWu65Z5uyb4WK1LOqubQ=";
        };

        postPatch = ''
          sed -i '/addopts/d' setup.cfg
        '';

        build-system = [
          setuptools
        ];

        dependencies = [
          defusedxml
          passlib
          vobject
          pika
          python-dateutil
          pytz # https://github.com/Kozea/Radicale/issues/816
        ] ++ passlib.optional-dependencies.bcrypt;

        doCheck = false;
      })
    ];

    doCheck = false;
  };
}