#!@zsh@/bin/zsh

logTag=${0:t}

exec 1> >(logger -t "$logTag" -p news.notice)
exec 2> >(logger -t "$logTag" -p news.error)

debug() { logger -t "$logTag" -p news.debug }

function notmuch {
    msg1=1
    while true; do
        result=$(env NOTMUCH_CONFIG=${HOME}/.notmuch-rss-config @notmuch@/bin/notmuch $@)
        if ! [[ "$result" =~ "already locked" ]]; then
            echo -nE "$result"
            return
        else
            [[ $msg1 == "1" ]] && echo "Already locked" >&2
            msg1=0
        fi
        sleep 2
    done
}

while {
    results=$(notmuch search --sort=oldest-first --output=messages "( tag:inbox AND is:media AND is:unread ) AND NOT ( tag:new OR tag:killed OR tag:failed OR tag:cached )")
    ids=("${(f)results}")
    for i in $checkedIds; do
        ids=(${ids#$i})
    done
    checkedIds=($checkedIds $ids)
} && [[ -n "${ids}" ]]; do
    url=""

    for id (${ids}); do
        systemctl --user --wait start $(systemd-escape --template=download-youtube@.service ${id})
    done
done