{ config, lib, pkgs, ... }:

with lib;

let
  cfg = config.services.bar;
in {
  options.services.bar = {
    enable = mkEnableOption "the Bar Inventory System";

    user = mkOption {
      type = types.str;
      default = "bar";
      description = "User to execute the daemon under";
    };

    group = mkOption {
      type = types.str;
      default = "bar";
      description = "Group to execute the daemon under";
    };

    stateDir = mkOption {
      type = types.path;
      default = "/var/lib/bar";
      description = "Directory for the daemon to store semi-transient state (encryption keys etc.)";
    };

    port = mkOption {
      type = types.int;
      default = 8080;
      description = "Port for the daemon to listen on";
    };

    host = mkOption {
      type = types.str;
      default = "localhost";
      description = "Host to bind to";
    };

    approot = mkOption {
      type = types.str;
      default = "/";
      description = "Subdirectory of the daemon-managed site relative to HTTP /; only useful when using a reverse proxy";
    };

    ipFromHeader = mkOption {
      type = types.bool;
      default = false;
      description = "Determine IP from a HTTP header";
    };

    thermoprintBaseURL = mkOption {
      type = with types; nullOr types.str;
      default = null;
      example = "http://localhost:80/thermoprint/api";
      description = "Thermoprint base url";
    };
  };

  imports = [ ./thermoprint-service.nix ];

  config = mkIf cfg.enable {
    assertions = [
      { assertion = config.services.postgresql.enable;
        message = "bar requires PostgreSQL";
      }
    ];

    nixpkgs.config.allowUnfree = true;

    packages.thermoprint.enable = true;

    users.users."${cfg.user}" = {
      group = cfg.group;
      description = "User for the Bar Inventory System";
      isSystemUser = true;
      home = cfg.stateDir;
      createHome = true;
    };

    users.groups."${cfg.group}" = {};

    nixpkgs.overlays = [(selfPkgs: superPkgs: {
      haskellPackages = superPkgs.haskellPackages.extend (selfH: superH: {
        bar = superPkgs.callPackage ./bar { haskellPackages = selfH; };
      });

      inherit (selfPkgs.haskellPackages) bar;
    })];

    systemd.services."bar" = {
      environment = {
        PORT = cfg.port;
        HOST = cfg.host;
        APPROOT = cfg.approot;
        IP_FROM_HEADER = cfg.ipFromHeader;
        TPRINT_BASEURL = mkIf (cfg.thermoprintBaseURL != null) cfg.thermoprintBaseURL;
      };

      bindsTo = [ "postgresql.service" ];
      after = [ "postgresql.service" ];
      wantedBy = [ "default.target" ];

      serviceConfig = {
        Type = "notify";
        User = cfg.user;
        Group = cfg.group;
        WorkingDirectory = cfg.stateDir;

        ExecStart = with pkgs; "${bar}/bin/bar";
      };
    };
  };
}