From d20393e077b8d97b18f4a224ddcb20caf6dac23b Mon Sep 17 00:00:00 2001
From: Gregor Kleen <gkleen@yggdrasil.li>
Date: Wed, 10 Sep 2025 15:57:26 +0200
Subject: ...

---
 .../shell/quickshell/Services/Brightness.qml       | 68 ++++++++++++++++++++++
 .../shell/quickshell/Services/Privacy.qml          | 63 ++++++++++++++++++++
 2 files changed, 131 insertions(+)
 create mode 100644 accounts/gkleen@sif/shell/quickshell/Services/Brightness.qml
 create mode 100644 accounts/gkleen@sif/shell/quickshell/Services/Privacy.qml

(limited to 'accounts/gkleen@sif/shell/quickshell/Services')

diff --git a/accounts/gkleen@sif/shell/quickshell/Services/Brightness.qml b/accounts/gkleen@sif/shell/quickshell/Services/Brightness.qml
new file mode 100644
index 00000000..545ef24f
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell/Services/Brightness.qml
@@ -0,0 +1,68 @@
+pragma Singleton
+
+import QtQml
+import Quickshell
+import Quickshell.Io
+import Custom as Custom
+
+Singleton {
+  id: root
+
+  property string subsystem: "backlight"
+  property string device: "intel_backlight"
+
+  property real currBrightness
+  property real exponent: 4
+
+  function calcCurrBrightness() {
+    if (!currFile.loaded || !maxFile.loaded)
+      return undefined;
+    const curr = Number(currFile.text());
+    const max = Number(maxFile.text());
+    const val = Math.pow(curr / max, 1 / root.exponent);
+    return val;
+  }
+
+  Component.onCompleted: root.currBrightness = root.calcCurrBrightness()
+  Connections {
+    target: currFile
+    onLoaded: root.currBrightness = root.calcCurrBrightness()
+  }
+  Connections {
+    target: maxFile
+    onLoaded: root.currBrightness = root.calcCurrBrightness()
+  }
+
+  onCurrBrightnessChanged: {
+    root.currBrightness = Math.max(0, Math.min(1, root.currBrightness));
+
+    const prev = root.calcCurrBrightness();
+    if (typeof prev === 'undefined' || Math.abs(root.currBrightness - prev) < 0.01)
+      return;
+
+    const max = Number(maxFile.text());
+    const actual = Number(currFile.text());
+    let curr = Math.max(0, Math.min(max, Math.pow(root.currBrightness, root.exponent) * max));
+    if (Math.round(curr) == actual && curr < actual)
+      curr = Math.max(0, actual - 1);
+    else if (Math.round(curr) == actual && curr > actual)
+      curr = Math.min(max, actual + 1);
+    // root.currBrightness = Math.pow(curr / max, 1 / root.exponent);
+    Custom.Systemd.setBrightness(root.subsystem, root.device, Math.round(curr));
+  }
+
+  FileView {
+    id: currFile
+    path: `/sys/class/${root.subsystem}/${root.device}/brightness`
+    blockAllReads: true
+    watchChanges: true
+    onFileChanged: reload()
+  }
+  FileView {
+    id: maxFile
+    path: `/sys/class/${root.subsystem}/${root.device}/max_brightness`
+    blockAllReads: true
+    watchChanges: true
+    onFileChanged: reload()
+  }
+}
diff --git a/accounts/gkleen@sif/shell/quickshell/Services/Privacy.qml b/accounts/gkleen@sif/shell/quickshell/Services/Privacy.qml
new file mode 100644
index 00000000..9c813e49
--- /dev/null
+++ b/accounts/gkleen@sif/shell/quickshell/Services/Privacy.qml
@@ -0,0 +1,63 @@
+pragma Singleton
+
+import QtQml
+import Quickshell
+import Quickshell.Services.Pipewire
+
+Singleton {
+  id: root
+
+  PwObjectTracker {
+    objects: Pipewire.nodes.values
+  }
+
+  enum Item {
+    Microphone,
+    Screensharing
+  }
+
+  readonly property list<var> activeItems: {
+    var items = [];
+    if (microphoneActive)
+      items.push(Privacy.Item.Microphone);
+    if (screensharingActive)
+      items.push(Privacy.Item.Screensharing);
+    return items;
+  }
+
+  readonly property bool microphoneActive: {
+    if (!Pipewire.ready || !Pipewire.nodes?.values) {
+      return false
+    }
+
+    for (const node of Pipewire.nodes.values) {
+      if (!node || (node.type & PwNodeType.AudioInStream) != PwNodeType.AudioInStream)
+        continue;
+
+      if (node.properties?.["stream.monitor"] === "true")
+        continue;
+
+      if (node.audio?.muted)
+        continue;
+
+      return true;
+    }
+
+    return false;
+  }
+
+  readonly property bool screensharingActive: {
+    if (!Pipewire.ready || !Pipewire.nodes?.values) {
+      return false
+    }
+
+    for (const node of Pipewire.nodes.values) {
+      if (!node || (node.type & PwNodeType.VideoInStream) != PwNodeType.VideoInStream)
+        continue;
+
+      return true;
+    }
+
+    return false;
+  }
+}
-- 
cgit v1.2.3