#!/usr/bin/env zsh

ret=0

logged() {
    printf ">>> ‘%s’ in %s\n" "$*" $(pwd) >&2
    ${@}
    ret=$?
    printf ">>> %d\n" $ret >&2
}

typeset -a cleanupList
cleanupList=()
cleanup() {
    for cmd in ${cleanupList}; do
        eval $cmd
    done
}
trap cleanup EXIT

typeset -a beamerAspects
beamerAspects=(43 169)
beamerAspect=$beamerAspects[1]

if [[ $beamerAspects[(i)${2:r:e}] -le $#beamerAspects ]]; then
    beamerAspect=${2:r:e}
    2=${2:r:r}.${2:e}
fi

base=(${2:r}.(md|lhs|tex)([1]))
metadata=(${2:r}.meta.yml([1]N))

gup -u ${base} ${metadata} preamble.tex

buildDir=$(pwd)

base=${base:A}
metadata=${metadata:A}
cd ${base:h}

input=${base}

typeset -a extraArgs
extraArgs=(-R -V "geometry=margin=2cm" -V "fontfamily=libertine" -H ${buildDir}/preamble.tex --listings --latex-engine=lualatex --filter=pandoc-citeproc --biblatex)


if [[ -n ${metadata} ]]; then
    input=$(mktemp)
    cleanupList+=("rm -v ${input}")

    typeset -a class
    class=()
    [[ ${base:e} == "tex" ]] && class=(-f latex)
    
    logged pandoc -f markdown -t native -s ${metadata} | head -n -1 >>${input}
    logged pandoc -R ${class} -t native ${base} >>${input}

    extraArgs+=(-f native)
fi

compileDir=$(mktemp -d)
cleanupList+=("cd /" "rm -rfv ${compileDir}")

if [[ ${base:t:r} == "presentation" ]]; then
    gup -u ${buildDir}/beamer-template.tex
    extraArgs+=(--template=${buildDir}/beamer-template.tex -M "aspectratio=${beamerAspect}")
fi

logged pandoc ${extraArgs} -o ${compileDir}/${base:t:r}.tex ${input} >&2

cd ${compileDir}
for f (bib); do
    printf "Checking for ‘%s’\n" ${base:h}/${f} >&2
    [[ -e ${base:h}/${f} ]] || continue
    logged rsync -av ${base:h}/${f} .
done

# cat -n ${base:t:r}.tex >&2

max=5
runs=0
run=true
while ${run} && [[ ${runs} -lt ${max} ]]; do
    output=$(mktemp)
    cleanupList+=("rm -v ${output}")
    logged lualatex ${base:t:r}.tex >${output} </dev/null
    ( return $ret ) || { logged cat ${output}; break }
    grep -C 2 -i "warning" ${output}
    run=false
    grep -Eq $'(\\(re\\)run Biber)|(Please rerun LaTeX)' ${output} && run=true
    [[ -e ${base:t:r}.bcf && runs -eq 0 ]] && logged biber ${base:t:r}
    runs=$((runs + 1))
done

cp -v ${base:t:r}.pdf $1