{ pkgs ? (import <nixpkgs> {})
}:

with pkgs.lib;
    
let
  sourceFilter = path: type: (hasPrefix (toString ./src ) path || (baseNameOf path == "blog.cabal"));
in rec {
  haskellPackages = pkgs.haskellPackages.override {
    overrides = self : super : {
      hakyll = pkgs.haskell.lib.overrideCabal super.hakyll (drv: {
        doCheck = false;
      });
    };
  };
  dirty-haskell = pkgs.stdenv.lib.overrideDerivation (haskellPackages.callPackage ./blog.nix {})
    (attrs :
      { src = builtins.filterSource sourceFilter ./.;
        shellHook = ''
          export PROMPT_INFO=${attrs.name}
        '';
      }
    );
  texEnv = with pkgs; texlive.combine {
    inherit (texlive) scheme-small standalone dvisvgm amsmath tikz-cd rsfs;
  };
  dirty-haskell-wrapper = pkgs.stdenv.mkDerivation rec {
    name = "dirty-haskell-wrapper";
    buildInputs = [ pkgs.makeWrapper ];
    buildCommand = ''
      mkdir -p $out/bin
      makeWrapper ${dirty-haskell}/bin/site $out/bin/dirty-haskell \
        --prefix PATH : ${texEnv}/bin
    '';
  };
}